lite asm-hjälp

$tiff · Inlägg av **$tiff** » 22 januari 2005, 07:58:30

Jag blir skogstokig. Varför funkar inte min enkla kod?

AT90S8515 på ett STK500, simulerar även i AVR Studio 4:

.include "8515def.inc"  ;Includes the 8515 definitions file

.org $000
rjmp RESET          		;Take a Relative Jump to the RESET Label 
.org $007
rjmp ISR_TOV0				;ISR-routine fpr timer0 overflow



; ---- Startup -----	
RESET:                  ;Reset Label
   ldi r16, 0b00001110
   out WDTCR, r16		; Set Watchdog to timeout ~1,0s
   
   ser r16				; 255 to set all pins output      
   out DDRB, r16      	; @ PORTB data direction Register
   ldi r16, 0b01010010 	; Good startup value
   out PORTB, r16		; @ PORTB

; ---- Setup timer0 interrupt -----
init_timer0:
   ldi r16,0b00000101		; Timer 0 on, prescaler: 1024
   out TCCR0,r16 			; 
 
   ldi r16,1<<TOV0			;
   out TIFR,r16 			; Clear TOV0 / clear pending interrupts

   ldi r16,1<<TOIE0
   out TIMSK,r16 			; Enable Timer/Counter0 Overflow Interrupt
   SEI						; Global interrupt on


; ---- Main loop -----
Loop:                  
nop			
nop 
nop			; Do nothing - wait for interrupt
nop
nop
WDR			; Watchdog reset
rjmp Loop


; ---- ISR routine -----
ISR_TOV0:
;push r17		; Push r17 in stack
;push r16		; Push r16 in stack
;in r16,SREG
;push r16		; Push SREG in stack

in r16,PORTB 	; Read Port B
inc r16 		; Icrease by one
out PORTB,r16 	; Write Port B

;pop r16			
;out SREG,r16	; Pop SREG from stack
;pop r16		; Pop r16 from stack
;pop r17		; Pop r17 from stack

reti			; Return from ISR

Jag vill alltså bara att portB (lysdioder) ska ändra sig varje interrupt (ca 5 ggr/s med 1,23 MHz klockpuls och 1024 i prescaler på en 8-bits timer).
Det tuffar på bra i AVR Studio tills den kommer in i ISRen, sen vägrar den hoppa ut därifrån - interruptet har väl hängt sig?

Detta är mitt första någerlunda meningsfulla asm-prgogram, så det kan mycket väl smugist sig in något fundamentalt fel

Dessutom har jag hämtat mycket inspiration från en appnote. Surt att det inte funkar då

Trodde det var min push-pop som var galen, men efter att ha kommenterat ut den så blev inget bättre.

Nog dax att sova lite

Icecap · Inlägg av **Icecap** » 22 januari 2005, 08:30:36

Jag kör inte med AVR men man ska väl resetta den bit som orsaker interrupten eller hur?

Alltså: Timern drar overflow-bitten, orsaker interrupten och ditt program måste sedan nolla den bitten i interruptrutinen.

Så fungerar det i alla fall på de andra MCU:n jag känner till.

Testa det, sen kanske det kör.

$tiff · Inlägg av **$tiff** » 22 januari 2005, 08:34:01

Den resettas automatiskt när den hoppar till ISR-vektorn (007 i detta fallet).
Har även provat resetta den manuellt, hjälpte inte.

erixon · Inlägg av **erixon** » 22 januari 2005, 10:32:08

Du har glömt att initsiera stackpekaren

Kod: Markera allt

ldi	r16,high(RAMEND) 
out	SPH,r16
ldi	r16,low(RAMEND)	 
out	SPL,r16

Det borde fixa biffen

karlstedt · Inlägg av **karlstedt** » 22 januari 2005, 10:33:26

Då jag simulerar detta hänger den sig inte i ISP, men den kör om programmet från början vilket beror på att du inte har initierat stackpekaren.
Testa med denna kod i den resetvektor

Kod: Markera allt

;***********************
 	ldi r16, low(RAMEND)
	out SPL, r16
	ldi r16, high(RAMEND)
	out SPH, r16
;***********************

Sedan vill jag nämna att det är reti som återställer interruptbiten och att spara undan SREG är inte heller nån dum idé

EDIT: För seg...

$tiff · Inlägg av **$tiff** » 22 januari 2005, 11:47:50

Göött!

Nu funkar det!

>> karlstedt

Jag sparar väl undan SREG på rätt sätt i min utkommenterade kod i ISRen?
Det kvittar väl i detta fallet eftersom main_loop inte påverkar SREG, men annars är det ytterst nödvändigt.

karlstedt · Inlägg av **karlstedt** » 22 januari 2005, 13:09:19

Japp, det ser fint ut!