Svenska ElektronikForumet

Kod: Markera allt

;;; 
;;; Read ADC2 (PB2) and output servo signal on PB0.
;;; ATtiny5 or 10 at default 1MHz.
;;;
        
#include "tn10def.inc"

.cseg
.org 0
        rjmp    init

init:   
        ;; ADC channel 2
        ldi     r16, 2
        out     ADMUX, r16
        ;; Disable digital input on PB2
        sbi     DIDR0, ADC2D
        ;; Enable ADC, presc 1:8 for 125kHz ADC-clock
        ldi     r16, (1<<ADEN) | (1<<ADPS1) | (1<<ADPS0)
        out     ADCSRA, r16

        ;; PB0 output.
        sbi     DDRB, PB0;

        ;; Timer0 50Hz PWM, 1us tick, mode 14 with ICR0 as TOP.
        ldi     r17, high(19999)
        ldi     r16, low(19999)
        out     ICR0H, r17
        out     ICR0L, r16

        ;; Start with 1.5 ms pulse-width
        ldi     r17, high(1500)
        ldi     r16, low(1500)
        out     OCR0AH, r17
        out     OCR0AL, r16

        ;; OC0A non inverting PWM, mode bit 1
        ldi     r16, (1<<COM0A1) | (1<<WGM01)
        out     TCCR0A, r16
        ;; mode bits 2 and 3, presc 1:1
        ldi     r16, (1<<WGM03) | (1<<WGM02) | (1<<CS00)
        out     TCCR0B, r16

.def    adc4l = r24
.def    adc4h = r25
.def    temp  = r16
.def    cnt   = r17
.def    zero  = r18

        clr     zero
loop:
        ;; Preload adc4 with minimum pulse width
        ldi     adc4l, low(998)
        ldi     adc4h, high(998)

        ;; Take four ADC samples and add them to adc4
        ldi     cnt, 4
adc_loop:
        sbi     ADCSRA, ADSC    ;Start conversion
adc_loop1:      
        sbic    ADCSRA, ADSC    ;Skip next if conversion finished
        rjmp    adc_loop1

        ;; adcn4 += ADCL
        in      temp, ADCL
        add     adc4l, temp     ;Add low byte
        adc     adc4h, zero     ;Add carry if set

        dec     cnt             ;Done it four times?
        brne    adc_loop        ;Otherwise do it again

        ;; Set OCR0A to 998 + ADCL + ADCL + ADCL + ADCL
        out     OCR0AH, adc4h
        out     OCR0AL, adc4l
        
        rjmp    loop

Kod: Markera allt

    while(1)
    {
        uint8_t i;
        uint16_t adc4;

        // Take four ADC samples, add them in adc4
        for (i = 0, adc4 = 0; i < 4; i++)
        {
            // Start a conversion
            ADCSRA |= (1<<ADSC);
            // wait until it's finished
            while (ADCSRA & (1<<ADSC))
                ; // Nothing
            adc4 += ADCL;
        }

        // Set PWM to 990 to 2010 ms from ADC.
        OCR0A = 990 + adc4;
        // OCR0B "inverted" servo signal
        OCR0B = 2010 - adc4;
    }