Svenska ElektronikForumet

Kod: Markera allt

#include <OneWire.h>
#include <DallasTemperature.h>
#include <PID_v1.h>

int gpustate = 0, pwmstate = 0, waterstate = 0;
int PWMpin1 = 9; //GPU fan
int PWMpin2 = 10; //PWM fan
int PWMpin3 = 3; //cooler fans
int PWMpin4 = 11; //air intake fan

OneWire ds(2);  // on pin 2
DallasTemperature sensors(&ds); // Pass our oneWire reference to Dallas Temperature. 
// arrays to hold device address
DeviceAddress gpusensor = {0x22, 0x16, 0xC3, 0x1A, 0x00, 0x00, 0x00, 0x33};
DeviceAddress pwmsensor = {0x22, 0x60, 0xBA, 0x1A, 0x00, 0x00, 0x00, 0x87};
DeviceAddress watersensor = {0x22, 0xA0, 0xBC, 0x1A, 0x00, 0x00, 0x00, 0x84};
int sensorsOK = 0;

int gpustarttemp = 39;
int gpustoptemp = 32;
double gpusetpoint = 41;
int pwmstarttemp = 36;
int pwmstoptemp = 32;
double pwmsetpoint = 40;
int waterstarttemp = 34;
int waterstoptemp = 32;
double watersetpoint = 35;

int minspeed = 50;
int intakeoffset = 40;
double gputemp, pwmtemp, watertemp;
double output1, output2, output3, output4;

PID gpuPID(&gputemp, &output1, &gpusetpoint, 75, 10, 0, REVERSE);
PID pwmPID(&pwmtemp, &output2, &pwmsetpoint, 75, 10, 0, REVERSE);
PID waterPID(&watertemp, &output3, &watersetpoint, 180, 50, 0, REVERSE);

int initsensors() {
  int ok = 0;
  
  // locate devices on the bus
  sensors.begin();
  
  if (sensors.getDeviceCount() == 3) {
    sensors.setResolution(gpusensor, 12);
    sensors.setResolution(pwmsensor, 12);
    sensors.setResolution(watersensor, 12);
    ok = 1;
  }
  
  return ok;
}

void setup()  { 
  //OSCCAL = 0x80;
  Serial.begin(9600);
  //Pins 9 and 10: controlled by timer 1
  //Setting 	Divisor 	Frequency
  //0x01 	 	1 	 	31250
  //0x02 	 	8 	 	3906.25
  //0x03  		64 	 	488.28125
  //0x04  		256 	 	122.0703125
  //0x05 	 	1024 	 	30.517578125

  TCCR1B = TCCR1B & 0b11111000 | 0x05;
  
  //Pins 11 and 3: controlled by timer 2
  //Setting 	Divisor 	Frequency
  //0x01 	 	1  		31250
  //0x02 	 	8 	 	3906.25
  //0x03  		32  		976.5625
  //0x04 	 	64 	 	488.28125
  //0x05 	 	128  		244.140625
  //0x06  		256  		122.0703125
  //0x07 	 	1024  		30.517578125

  TCCR2B = TCCR2B & 0b11111000 | 0x07;
  
  // declare pin 9 to be an output:
  pinMode(PWMpin1, OUTPUT);
  pinMode(PWMpin2, OUTPUT);
  pinMode(PWMpin3, OUTPUT);
  pinMode(PWMpin4, OUTPUT);
  
  // locate devices on the bus
  sensorsOK = initsensors();

  gpuPID.SetMode(AUTOMATIC);
  pwmPID.SetMode(AUTOMATIC);
  waterPID.SetMode(AUTOMATIC);
} 

void loop()  { 
  if (sensorsOK == 1) {
    sensors.requestTemperatures();
    gputemp = sensors.getTempC(gpusensor);
    pwmtemp = sensors.getTempC(pwmsensor);
    watertemp = sensors.getTempC(watersensor);
  }
  else sensorsOK -= 1; //countdown to reinit sensor
  if (sensorsOK < -10) {
    sensorsOK = initsensors();
  }
  
  Serial.print("GPU temperature = ");
  Serial.println(gputemp);
  Serial.print("PWM temperature = ");
  Serial.println(pwmtemp);
  Serial.print("Water temperature = ");
  Serial.println(watertemp);

  switch (gpustate) {
    case 0: //stopped
      if ((gputemp > gpustarttemp)||((int) gputemp == 0)) {
        analogWrite(PWMpin1, 200); //startup boost until next cycle
        gpustate = 1;
      }
      break;
      
    case 1: //running
      gpuPID.Compute();
      
      if (output1 < minspeed) output1 = minspeed;
      if ((int) gputemp == 0) { //could not read sensors, set full speed
        //Serial.println("Full speed");
        output1 = 255;
      }
      if (output1 > 255) output1 = 255;

      Serial.print("GPU fan output: ");
      Serial.println(output1);   
      analogWrite(PWMpin1, output1);
      
      if ((gputemp < gpustoptemp)&&((int) gputemp != 0)) {
        analogWrite(PWMpin1, 0);
        gpustate = 0;
      }
      break;
  }

  switch (pwmstate) {
    case 0: //stopped
      if ((pwmtemp > pwmstarttemp)||((int) pwmtemp == 0)) {
        analogWrite(PWMpin2, 200); //startup boost until next cycle
        pwmstate = 1;
      }
      break;
      
    case 1: //running
      pwmPID.Compute();
      
      if (output2 < minspeed) output2 = minspeed;
      if ((int) pwmtemp == 0) { //could not read sensors, set full speed
        //Serial.println("Full speed");
        output2 = 255;
      }
      if (output2 > 255) output2 = 255;

      Serial.print("PWM fan output: ");
      Serial.println(output2);   
      analogWrite(PWMpin2, output2);
      
      if ((pwmtemp < pwmstoptemp)&&((int) pwmtemp != 0)) {
        analogWrite(PWMpin2, 0);
        pwmstate = 0;
      }
      break;
  }
  
    switch (waterstate) {
    case 0: //stopped
      if ((watertemp > waterstarttemp)||((int) watertemp == 0)) {
        analogWrite(PWMpin3, 200); //startup boost until next cycle
        analogWrite(PWMpin4, 200); //startup boost until next cycle
        waterstate = 1;
      }
      break;
      
    case 1: //running
      waterPID.Compute();

      output4 = output3 + intakeoffset;
      
      if (output3 < minspeed) output3 = minspeed;
      if (output4 < minspeed) output4 = minspeed;
      if ((int) watertemp == 0) { //could not read sensors, set full speed
        //Serial.println("Full speed");
        output3 = 255;
        output4 = 255;
      }
      if (output3 > 255) output3 = 255;
      if (output4 > 255) output4 = 255;

      Serial.print("Water cooler fan intake output: ");
      Serial.print(output4);
      Serial.print(", radiator output: ");
      Serial.println(output3);
      analogWrite(PWMpin3, output3);
      analogWrite(PWMpin4, output4);      

      if ((watertemp < waterstoptemp)&&((int) watertemp != 0)) {
        analogWrite(PWMpin3, 0);
        analogWrite(PWMpin4, 0);
        waterstate = 0;
      }
      break;
  }
  
  // wait for 1000 milliseconds 
  delay(1000);
}