Inga uppdateringar på ett tag. Men jag har pysslat vidare ändå. Sist jag felsökte och inte byggde saker och hämtade rack så höll jag på att felsöka varför testprogrammet för RL8A, diskkontrollern inte fungerar längre. Så jag körde lite testprogram:
maindec-08-djkka-c-pb1:
Testprogram för CPU:n, testar alla instruktioner på M8315 kortet, men inte databreak (DMA) eller IRQ om man inte har testhårdvara (vilket jag inte har). TEST OK
maindec-08-AJRLAC:
Diskless controller test. Testar logiken på diskkontrollern utan att man behöver en diskstation inkopplad. Detta testet har fungerat. TEST FAIL
maindec-08-dhkma:
PDP-8E memory execiser, testar minnet. TEST OK
CHEKMO-II:
Schack på PDP-8, jag vet att detta funkar på min 8/L så jag testade det på 8a. TEST OK
djexc-b:
CPU execiser, testar 8A CPU:n. Alla korten till viss del. Man kan välja om man vill testa med M8316 (som är DKC8A, Option #1). Option #1 innehåller RTC interrupt (100Hz IRQ), anslutning till programmers console, serieporten för seriekonsolen och lite parallell IO. Man testar bara RTC och serieporten om man vill.
Testade och köra utan att testa M8316. TEST OK
Med M8316. TEST FAIL!
Jag fungerade ut att förmodligen var det RTC interruptet som inte fungerade och bestämde mig för att läsa på lite om IRQ. Jag valde boken
"Introduction to programming" som jag har tre exemplar av. Tyvärr är länken till andra utgåvan och jag har läst fjärde så den är inte så relevant. Jag hittade ett program som jag skrev in som använder IRQ för att läsa och skriva till seriekonsolen. Jag assemblerade det på PC under Linux med
palbart. Jag tänkte att jag skulle testa det och sen modifiera det för att testa RTC IRQ:t.
Kod: Markera allt
*0 /FIRST INSTRUCTION
/AFTER AN INTERRUPT:
0 /STORE RETURN ADDRESS
JMP I 2 /JUMP TO SERVICE ROUTINE
SERVE /POINTER TO SERVICE ROUTINE
*200 /INITIALIZAITION ROUTINE:
START, CLA CLL /CLEAT ACCUMULATOR AND LINK
DCA MODE /SET MODE FOR INPUT
TAD K1777 /INITIALIZE DATA
DCA BUFFER /BUFFER POINTER
ION /TURN INTERRUPT ON
/BACKGROUND PROGRAM:
ROTATE, CLA CLL IAC /SET ACCUMULATOR BIT 11
ISZ COUNT /COUNT
JMP .-1 /TWICE
ISZ COUNT /THROUGH
JMP .-1 /DELAY LOOP
RAL /ROTATE BIT LEFT
JMP ROTATE+1 /RETURN TO DELEAY LOOP
/SERVICE ROUTINE:
SERVE, DCA AC /SAVE ACCUMULATOR
GTF /SAVE INTERRUPTS
DCA FLAGS /FLAGS AND LINK
KSF /KEYBOARD FLAG RAISED?
SKP /NO: CHECK PRINTER FLAG
JMP KB /YES: SERVICE KEYBOARD
TSF /PRINTER INTERRUPT?
SKP /NO: SKIP FOR EXIT
JMP TP /YES: SERVICE PRINTER
CAF /CLEAR ALL FLAGS
JMP EXIT /AND RETURN
/KEYBOARD INTERRUPT ROUTINE:
KB, KCC /CLEAR KEYBOARD FLAG
TAD MODE /CURRENTLY IN
SZA CLA /INPUT MODE?
JMP EXIT /NO: RETURN TO BACKGROUND
ISZ BUFFER /YES: INCREMENT POINTER
KRB /READ THE CHARACTER
TLS /ECHO ON PRINTER
DCA I BUFFER /STORE THE CHARACTER
TAD I BUFFER /WAS THE
TAD MPER /CHARACTER A
SZA CLA /PERIOD?
JMP EXIT /NO: RETURN TO BACKGROUND
TAD K1777 /YES: RESET BUFFER
DCA BUFFER /POINTER TO TYPE
CLA CMA /THE CHARACTERS
DCA MODE /SET MODE FOR OUTPUT AND
JMP EXIT /RETURN TO BACKGROUND
/PRINTER OUTPUT ROUTINE:
TP, TCF /CLEAR PRINTER FLAG
TAD MODE /CURRENTLY IN
SNA CLA /OUTPUT MODE?
JMP EXIT /NO: RETURN TO BACKGROUND
ISZ BUFFER /YES: INCREMENT POINTER
TAD I BUFFER /GET CHARACTER FROM BUFFER
TLS /PRINT IT
TAD MPER /WAS THE CHARACTER
SZA CLA /A PERIOD?
JMP EXIT /NO: RETURN TO BACKGROUND
DCA MODE /YES: SET MODE FOR INPUT
TAD K1777 /RESET BUFFER
DCA BUFFER /POINTER AND
JMP EXIT /RETURN TO BACKGROUND
/EXIT ROUTINE:
EXIT, TAD FLAGS /GET FLAGS AND LINK
RTF /RESTORE FLAGS AND LINK
CLA /CLEAR ACCUMULATOR
TAD AC /RESTORE ACCUMULATOR
JMP I 0 /RETURN TO BACKGROUND
COUNT, 0 /DELAY LOOP COUNTER
MODE, 0 /MODE SWITCH
K1777, 1777 /LAST LOC BEFORE BUFFER
BUFFER, 0 /DATA BUFFER POINTER
AC, 0 /SAVE ACCUMULATOR
FLAGS, 0 /SAVE FLAGS AND LINK
MPER, -256 /NEGATIVE OF ASCII CODE
$
Jag laddade i 8A och det fungerade inte. Så något med IRQ är trasigt. För att vara säker på att programmet var helt så laddade jag det i 8/L och där fungerade det!
Så nu har jag ett litet program som inte fungerar vilket det gör lättare att hitta felet. Jag följde IRQ REQ signalen fram till CPU:n och dit kommer den. Tittar man på frontpanelen så kan man se att interrupt är påslaget och att "interrupt request" biten sätts. När interruptet kommer så ska datorn hoppa till en subrutin (JMS instruktionen). Denna ligger alltid på adress 0 (noll). Hit kommer man inte. Så jag vet på ett ungefär vad jag ska leta efter!
Mäter på interruptet på DKC8A
Har fått in 8/L i racket, fick dock bygga lite sladdar för att få tag på serieporten och 110V.
